;;; Get H-alpha profiles at QS disk canter and QS near target
;;; full profile important -> also do linearity correction!

FUNCTION readavg, file, num, gamma=gamma
x = findgen(1024)
IF keyword_set(gamma) THEN $
  g_table = interpol(x/1023, 1023*(x/1023)^gamma(0), x)
openr, unit, file, /get
p = assoc(unit, uintarr(1296, 1030), 2880)
sum = 0.
FOR i=0, num-1 DO BEGIN
    b1 = fix(ishft(p(16:*, 2:1025, i), -6))
    IF keyword_set(gamma) THEN $
      b1 = fix(b1+gamma(1)*g_table(b1))
    sum += avg(b1)
ENDFOR
free_lun, unit
return, sum/num
END


;;; RC has no nonlinearity -> only for H-alpha
gamma = [0.089, 731]

d_rc = readavg(findfile('Calib/Ha-scan-dark*GRAB4-0'), 5)
d_ha = readavg(findfile('Calib/Ha-scan-dark*GRAB5-0'), 5)

f_rc_cen = findfile('Calib/Ha-scan-cent*GRAB4-0', count=nc)
f_rc_pla = findfile('Calib/Ha-scan-plage*GRAB4-0')
f_ha_cen = findfile('Calib/Ha-scan-cent*GRAB5-0')
f_ha_pla = findfile('Calib/Ha-scan-plage*GRAB5-0')

p_cen = fltarr(nc, 2)
p_pla = fltarr(nc, 2)

FOR i=0, nc-1 DO BEGIN
    p_cen(i, 0) = readavg(f_ha_cen(i), 5, ga=gamma)-d_ha
    p_cen(i, 1) = readavg(f_rc_cen(i), 5)-d_rc
    p_pla(i, 0) = readavg(f_ha_pla(i), 5, ga=gamma)-d_ha
    p_pla(i, 1) = readavg(f_rc_pla(i), 5)-d_rc
ENDFOR

save, p_cen, p_pla, d_rc, d_ha, file='profiles.save'

END